home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 8
/
FM Towns Free Software Collection 8.iso
/
t_os
/
nachel
/
nachle11.bas
next >
Wrap
BASIC Source File
|
1994-06-01
|
4KB
|
125 lines
10 '★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
20 '☆★☆★☆★☆★☆ ナックル v1.1 ★☆★☆★☆★☆★☆★☆★
30 '★☆★☆★☆★☆★ Presented by T.Koizumi ☆★☆★☆★☆★☆★☆★☆
40 '☆★☆★☆★☆★☆ SINCE 1993-1994 ★☆★☆★☆★☆★☆★☆★
50 '★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
60 SCREEN@0
70 COLOR 7,0
80 CLS
90 CONSOLE 3,21,2
100 ON ERROR GOTO *エラー
110 '
120 '▼タイトル表示
130 SYMBOL ( 0, 0),"ナックル v 1.1 PRESENTED BY T.Koizumi SINCE 1993-1994",1,1,7
140 SYMBOL (20,20),"(要RAM:2MB TOWNS-II推奨 ハードディスク推奨 ビデオカード必須)",1,1,7
150 '
160 '▼諸事項設定
170 INPUT "保存するドライブを入力してください([EXIT]で終了)。",D$
180 IF D$="EXIT" OR D$="exit" THEN END
190 IF LEN(D$)<>1 THEN 150
200 PRINT
210 '
220 INPUT "ファイル名を入力してください(拡張子を付けずに4字以内,[EXIT]で終了)。",F$
230 IF LEN(F$)<1 OR LEN(F$)>4 THEN 220
240 IF F$="EXIT" OR F$="exit" THEN END
250 PRINT
260 '
270 INPUT "何枚連続で取りますか?(1~9999枚)",I
280 IF I<1 OR I>=10000 THEN 250
290 '
300 I$=AKCNV$(MID$(STR$(I),2))
310 DD$=AKCNV$(D$)
320 '
330 '▼操作説明
340 PRINT
350 PRINT
360 LOCATE 25
370 PRINT " ★ 操 作 説 明 ★"
380 PRINT
390 PRINT " 1.取りたい画像があったときにリターンキーを押します。取り込んでください。画像は 随時保存されます。"
400 PRINT " 2.すると、ドライブ"+DD$+"に ["+F$+"****.tif] というファイル名で保存されます。"
410 PRINT " 3.保存が完了したら、自動的に取り込み画面に戻ります。"
420 PRINT " (戻らない時は、リターンキーを押してみてください。)"
430 PRINT " 4."+I$+"枚取り込んだ時点でメニューに戻ります。"
440 PRINT
450 PRINT " ◎ 尚、編集途中でもブレークキーで中断できます。"
460 PRINT
470 PRINT
480 PRINT " *** リターンで取り込み開始します ***"
490 X$=INPUT$(1)
500 '
510 '▼ビデオ画面取り込み
520 SCREEN@ 1
530 CLS
540 SPRITE ON
550 SINPUT
560 A$=INPUT$(1)
570 '
580 '▼保存処理
590 T=T+1
600 T$=STR$(T)
610 T$=MID$(T$,2)
620 SAVE@ D$+":"+F$+T$+".tif",(0,0)-(319,239)
630 WAIT 20
640 'SINPUT
650 IF T=I THEN 680 ELSE 590
660 '
670 '▼終了告知
680 SPRITE OFF
690 CLS
700 LOCATE 12,11
710 PRINT "*** 終了しました。リターンキーを押して下さい。 ***"
720 A$=INPUT$(1)
730 CLS
740 GOTO 60
750 '
760 '▼エラー処理
770 '
780 *エラー
790 SPRITE OFF
800 CLS
810 IF ERR=53 THEN 990
820 IF ERR=67 THEN 1080
830 IF ERR=72 THEN 990
840 IF ERR=73 THEN 1170
850 '
860 LOCATE 21,9
870 PRINT "*** エラーが発生しました ***"
880 LOCATE 28,11
890 PRINT USING "エラー番号・・・・・・・ ###";ERR
900 LOCATE 28,12
910 PRINT USING "エラー発生行・・・・・####";ERL
920 LOCATE 11,14
930 PRINT "Towns Menuに戻ります。何かキーを押してください。"
940 '
950 A$=INPUT$(1)
960 SYSTEM
970 '
980 '▼ディスクが入っていない
990 LOCATE 11,11
1000 PRINT "*** 指定されたドライブにディスクがありません。 ***"
1010 LOCATE 20,13
1020 PRINT " ディスクを入れ、何かキーを押してください。"
1030 '
1040 A$=INPUT$(1)
1050 RESUME 520
1060 '
1070 '▼ディスクに空きがない
1080 LOCATE 15,11
1090 PRINT "*** ディスクに空き領域がありません。 ***"
1100 LOCATE 11,13
1110 PRINT "空き領域のあるディスクを入れ、何かキーを押してください。"
1120 '
1130 A$=INPUT$(1)
1140 RESUME 520
1150 '
1160 '▼ディスクが書き込み禁止
1170 LOCATE 12,11
1180 PRINT "*** ディスクにプロテクトがかかっています。 ***"
1190 LOCATE 6,13
1200 PRINT "プロテクトのかかっていないディスクを入れ、何かキーを押してください。"
1210 '
1220 A$=INPUT$(1)
1230 RESUME 520
1240 '